Construction Set Der Scriptthread

Mercarryn schrieb:
Ja, ich hatte das Script auf den betreffenden NPC gelegt. Wenn ich als Global anlege, könnte ich doch noch mehr Teleports für weitere NPCS einbauen oder nicht? Dann müsste ich nur die Zeitvorgaben als Bedingung einstellen und würde mir die vielen einzelnenen Scripts sparen ( die NPCS sollen sowas wie ne Art Tagesverlauf haben)
Zum Vergrößern anklicken....
falls du weitere Orientierung brauchst kannst du hier mal reinschnuppern ... macht im Prinzip genau das was du vorhast - nur halt mit den Vanilla-NPCs.
 
  • Like
Reaktionen: Mercarryn
Killfetzer schrieb:
In einem meiner PIs habe ich eine identische Plattform verwendet:
Code: 
begin dg_platform_falle07

short doOnce

if ( GetStandingPC == 1 )
    if ( GetPos Z >= 11900 )
        if ( doOnce == 0 )
            PlaySound "cent steam roar"
            MessageBox "Die Plattform trägt Euch nicht."
            set doOnce to 1
        endif
        MoveWorld z -200
        return
    endif
endif

if ( GetPos Z < 13400 )
    if (doOnce==1)
        set doOnce to 0
    endif
    MoveWorld z 75
endif

end
Zum Vergrößern anklicken....
was genau bewirkt das?
Da hat es ja eine Messagebox drin...
und kann es sein, dass die nur zum heruntergehen geignet ist, also nur weil es irgendwie nur ein GetStandingPc hat und kein else(if)
 
BoneHead schrieb:
was genau bewirkt das?
Da hat es ja eine Messagebox drin...
und kann es sein, dass die nur zum heruntergehen geignet ist, also nur weil es irgendwie nur ein GetStandingPc hat und kein else(if)
Zum Vergrößern anklicken....

Es macht genau das, was du beschrieben hast. Da es bei mir als Falle gedacht ist, spielt es beim Auslösen einen Sound ab und zeigt eine MessageBox, die kannst du aber auch ohne weiteres löschen.

Ansonsten, versuche einfach mein Script zu verstehen, spiele damit rum. Nur so lernst du Scripten. :)
 
ok also ich versuchs mal
PS: hiess das PI zufäligerweise "Duellgilde"?
diese message kannte ich von da und das PI ist von dir. Nur, irgendwie wurde die falle niemals richtig ausgelöst. Es kam nur die Message...
Na egal, ich versuchs mal

Edit: hab mal ein bisschen "herumgespielt".
Das script funktioniert einigermassen. Problematisch ist nur die tatsache, dass die 3952 einheiten höhe in knapp einer sekunde ausgeführt werden, also viel zu schnell. Das ist kein mystischer, unsichtbarer lift mehr, sondern eher ein raketenstart ohne raktete:-D

Edit2: es ist nicht mal so schlimm, es ist schlimmer!
der player fällt durch die plattform (übrigens die Unsichtbare plattform editormarkerbox_1.nif) hindurch und bekommt die messagebox die ich einprogrammiert hab gleich 3 mal...
mein script sieht jetzt so aus:
Code: 
begin unsichtbarerlift1_script

short doOnce

if ( GetStandingPC == 1 )
    if ( GetPos Z >= 1337)
        if ( doOnce == 0 )
            set doOnce to 1
        endif
        playsound "windbag"
        MoveWorld z 3951
        messagebox "Bitte aussteigen!"
        return
    endif
endif

if ( GetPos Z == 5288 )
    if ( GetStandingPC == 0 )
        if (doOnce==1)
        set doOnce to 0
        endif
    MoveWorld z -3951
    endif
endif

end

Edit3: ich hab mal "weitergespielt" Die plattform will sich nun garnicht mehr bewegen, aber ich denke mal, dass sie langsamer wäre, wenn ich sie zum laufen bringen würde:
Code: 
begin unsichtbarerlift2_script

short doOnce

if ( GetStandingPC == 1 )
    if ( GetPos Z <= 3094)
        if ( doOnce == 0 )
            set doOnce to 1
        endif
        playsound "windbag"
        MoveWorld z 200
        return
    endif
endif

if ( GetPos Z >= 19094 )
    if ( getstandingPc == 1 )
        messagebox "Bitte aussteigen!"
    elseif ( GetStandingPC == 0 )
        if (doOnce==1)
        set doOnce to 0
        endif
    MoveWorld z -100
    endif
endif

end

Edit4: Hab eine Lösung gefunden:
Code: 
begin unsichtbarerlift2_script

short doOnce

if ( menumode == 1 )
    return
endif

if ( GetPos Z == 19094 )
    if ( GetStandingPC == 1 )
    return
    endif
endif

if ( GetPos Z == 3094 )
    if ( GetStandingPC == 0 )
    return
    endif
endif

if ( GetstandingPC == 1 )
    if ( GetPos Z >= 3094 )
        MoveWorld Z 200
        return
    endif
endif

if ( GetstandingPC == 0 )
    if ( GetPos Z <= 19094 )
        Moveworld Z -200
        return
    endif
endif

end

Edit5: Doch nicht...
Er hält nicht an wenn er oben ist

Edit6: jetzt macht er alles richtig, aber er fährt nicht mehr zurück wenn er erst einmal oben ist. Wenn ich aber einen Luftsprung mache, wechselt er sofort die richtung, aber nur wenn er nicht oben ist:
Code: 
begin unsichtbarerlift2_script

short doOnce

if ( menumode == 1 )
    return
endif

if ( GetStandingPC == 1 )
    if ( GetPos Z == 19094 )
        return
    endif
endif

if ( GetStandingPC == 0 )
    if ( GetPos Z == 3094 )
        return
    endif
endif

if ( GetstandingPC == 1 )
    if ( GetPos Z >= 3094 )
        if ( GetPos Z < 19094 )
            MoveWorld Z 200
            return
        endif
    endif
endif

if ( GetstandingPC == 0 )
    if ( GetPos Z <= 19094 )
        if ( GetPos Z > 3094 )
            Moveworld Z -200
            return
        endif
    endif
endif

end
 
Zuletzt bearbeitet:
BoneHead schrieb:
ok also ich versuchs mal
PS: hiess das PI zufäligerweise "Duellgilde"?
Zum Vergrößern anklicken....

Zufälligerweise ja ;)

Edit6: jetzt macht er alles richtig, aber er fährt nicht mehr zurück wenn er erst einmal oben ist. Wenn ich aber einen Luftsprung mache, wechselt er sofort die richtung, aber nur wenn er nicht oben ist:
Code: 
begin unsichtbarerlift2_script

short doOnce

if ( menumode == 1 )
    return
endif

if ( GetStandingPC == 1 )
    if ( GetPos Z == 19094 )
        return
    endif
endif

if ( GetStandingPC == 0 )
    if ( GetPos Z == 3094 )
        return
    endif
endif

if ( GetstandingPC == 1 )
    if ( GetPos Z >= 3094 )
        if ( GetPos Z < 19094 )
            MoveWorld Z 200
            return
        endif
    endif
endif

if ( GetstandingPC == 0 )
    if ( GetPos Z <= 19094 )
        if ( GetPos Z > 3094 )
            Moveworld Z -200
            return
        endif
    endif
endif

end
Zum Vergrößern anklicken....

Genau das soll das Script auch bewirken, so hatte ich dich verstanden (also die Richtungsumkehr, wenn man nicht draufsteht). Soll sich das Ding wie ein normaler Lift bewegen, der nur durch das Draufstehen ausgelöst ist, würde ich eine ganz andere Scriptstruktur vorschlagen.

Code: 
begin my_script

short state

if ( MenuMode == 1 )
  return
endif

if ( state == 0 )  ;Fahrstuhl ist in Ausgangsposition
  if ( GetStandingPC == 1 )
    set state to 1
  endif
endif

if ( state == 1 ) ;ab hier normale Fahrstuhlsequenz. state 1 nach oben fahren, state 2 nach unten. 
...
endif

end

Exox schrieb:
Kann es sein das man für das Beschwörungsscript Tribunal und/oder Bloodmoon benötigt?
Zum Vergrößern anklicken....

Eigentlich nicht. Die Befehle sind alle aus Originalmorrowind. Kann aber sein, dass sie in der Originalversion verbuggt waren (wie sehr viele) und erst seit Tribunal korrekt laufen.
 
Hab jetzt mal mein Teleport-Script für den Tagesablauf der NPCS erstellt und getestet, leider funktioniert es noch immer nicht.

Als Global habe ich MNCE_Teleport mit Type "Short" und Value 0 angelegt. Anschließend sieht mein Teleport-Script wie folgt aus:

PHP: 
begin "MNC Dorusat teleport"


short state

if (MNCE_Teleport == 0 )
    if ( GameHour > 21 )
MNC_Amassos_Dorusat->PositionCell "Ebenherz, Dorusat Amassos Haus" 3980, 4170, 16018, 147
  set MNCE_Teleport to 1
    elseif ( MNCE_Teleport == 1 )
         if ( GameHour > 7 )
                if ( GameHour < 21 )
MNC_Amassos_Dorusat->PositionCell "Ebenherz, Hafenviertel" 20682 ,-111455, 715, 228
set MNCE_Teleport to 0
    endif
  endif
endif
endif

end
Dieses Script liegt jetzt nicht auf dem entsprechenden Charakter ab, weil es ja laut Lexa (sorry, ich kann mir nie die Tastenkombi für das Pfundzeichen merken) nichts bringen würde.

Anschließend das ganze getestet, aber leider hat sich der NPC nach der jeweiligen Uhrzeit teleportiert. Und wahrscheinlich liegt der Fehler darin wieder im Detail. Oder ist ein bestimmtes Addon notwendig dafür?
 
Mercarryn schrieb:
Als Global habe ich MNCE_Teleport mit Type "Short" und Value 0 angelegt.
Zum Vergrößern anklicken....

Warum? Also warum eine globale Variable? Wenn du statt dessen die von dir bereits deklarierte lokale Variable state nehmen würdest, kalppt es auch und du müllst den Speicher nicht mit einer weiteren globalen Variable voll.

Lexa (sorry, ich kann mir nie die Tastenkombi für das Pfundzeichen merken)
Zum Vergrößern anklicken....

£ = Alt + 156 ;)

Anschließend das ganze getestet, aber leider hat sich der NPC nach der jeweiligen Uhrzeit teleportiert. Und wahrscheinlich liegt der Fehler darin wieder im Detail. Oder ist ein bestimmtes Addon notwendig dafür?
Zum Vergrößern anklicken....

Das Script ist soweit ich das sehe korrekt. Allerdings erfordert es einen Durchlauf bis es synchron mit der Uhrzeit ist. Vielleicht ist das dein Problem. Zum Beispiel wenn es bei deinem Test gerade zwischen 0 und 7 Uhr ist, wird der erste Teleport erst ausgelöst, wenn es wieder 21 Uhr ist.

PS: Wenn du deinen Quellcode einrückst, mach es doch auch bitte richtig.
 
  • Like
Reaktionen: Mercarryn
Killfetzer schrieb:
Genau das soll das Script auch bewirken, so hatte ich dich verstanden (also die Richtungsumkehr, wenn man nicht draufsteht). Soll sich das Ding wie ein normaler Lift bewegen, der nur durch das Draufstehen ausgelöst ist, würde ich eine ganz andere Scriptstruktur vorschlagen.

Code: 
begin my_script

short state

if ( MenuMode == 1 )
  return
endif

if ( state == 0 )  ;Fahrstuhl ist in Ausgangsposition
  if ( GetStandingPC == 1 )
    set state to 1
  endif
endif

if ( state == 1 ) ;ab hier normale Fahrstuhlsequenz. state 1 nach oben fahren, state 2 nach unten. 
...
endif

end
Zum Vergrößern anklicken....
ich glaub, du hast mich schon richtig verstanden. er soll sofort umkehren, sobald ich nicht mehr drauf bin, das macht er auch, aber nur, wenn er nicht ganz oben ist. Am ziel angekommen, will er sich weder auf noch ab bewegen
 
Zuletzt bearbeitet:
Killfetzer schrieb:
Warum? Also warum eine globale Variable? Wenn du statt dessen die von dir bereits deklarierte lokale Variable state nehmen würdest, kalppt es auch und du müllst den Speicher nicht mit einer weiteren globalen Variable voll.

...

Das Script ist soweit ich das sehe korrekt. Allerdings erfordert es einen Durchlauf bis es synchron mit der Uhrzeit ist. Vielleicht ist das dein Problem. Zum Beispiel wenn es bei deinem Test gerade zwischen 0 und 7 Uhr ist, wird der erste Teleport erst ausgelöst, wenn es wieder 21 Uhr ist.
...
Zum Vergrößern anklicken....

Die globale Variable hatte ich angelegt, weil ich £exa so verstanden habe, dass diese angelegt werden müsste. Ausserdem hab ich mal Tommys Rat befolgt und mir das Plug-In angesehen, hier wird auch mit Globalen Variablen gearbeitet. Hab dann versucht, mit state zu arbeiten, aber auch hier klappt es leider nicht.

Kann es sein, dass ich erst die Bedingung abfragen muss BEVOR ich das Script starte lasse? Das schien jedenfalls so der Fall zu sein...
Langsam verzweifel ich an dem drecks Script...:headwall:

Sorry wegen dem Einrücken mit dem Quell-Code, da hab ich etwas geschludert.
 
Mercarryn schrieb:
Kann es sein, dass ich erst die Bedingung abfragen muss BEVOR ich das Script starte lasse? Das schien jedenfalls so der Fall zu sein...
Zum Vergrößern anklicken....

Nein, das geht ja nicht. Du musst wenn man so will, eine zusätzliche Bedingung einbauen, die deinen NPC beim ersten Start des Scripts an die richtige Stelle bringt.

Code: 
begin "MNC Dorusat teleport"

short state

if ( state == 0 )  ;sorgt dafür, dass der NPC beim ersten Aufruf an der richtigen Stelle steht, Annahme NPC steht im Editor drinnen
  if ( GameHour > 7 )
    if ( GameHour < 21 )
      set state to 2
      NPC->PositionCell "draußen"
      return
    endif
  endif
  set state to 1
endif

if ( state == 1 )
  if ( GameHour > 7 )
    set state to 2
    NPC->PositionCell "draußen"
  endif
elseif ( state == 2 )
  if ( GameHour > 21 )
    set state to 1
    NPC->PositionCell "drinnen"
  endif
endif

end
 
Ich weiß zwar nicht ob das hier richtig reingehört, aber einen eigenen Thread zu eröffnen wäre auch blöd.

Wenn man ein "Static" zu einem "Activator" macht, kann man den dann mithilfe eines Scripts dauerhaft vergrößern (also ingame)? Ich denke es müsste funktionieren (meines Wissens geht es aber nur bis zehn), aber ich habe momentan nicht wirklich Ahnung vom Scripten, deswegen frage ich hier nach.
 
Ja, kannst du. Deine Informationen sind so richtig. Allerdings gibt es keine Garantie, dass die Kollisionsabfrage bei größeren Werten als 2 noch funktioniert.

Der Befehl heißt SetScale und muss bei jedem Zellenwechsel aufgerufen werden, also:

Code: 
begin my_script

if ( CellChanged == 1 )
  SetScale 10
endif

end
 
  • Like
Reaktionen: 1 Person
Und das mit der Kollision kann man nicht regeln, ohne an der Mesh rumzuspielen, oder? Hm..., aber falls man das vergrößert und darum Kollisionsboxen macht, müsste es ja gehen...
 
Ich hätte auch mal ein Problem:

Folgendes Script steuert ein Rätsel meiner Mod. Meistens funktioniert es ohne Probleme, aber manchmal (reproduzierbar auf verschiedenen Rechnern) wird ein EXPRESSION Fehler mit der näheren Begründung Infix To Postfix ausgelöst in dem Moment, wenn ( GetDistance Player < 1150 ) erfüllt wird.

Ich habe nicht die geringste Ahnung warum, warum es nur manchmal auftritt und warum drei inhaltlich identische Scripte (halt mit anderen Rätseln) problemlos funktionieren. Ich habe das Script sogar bereits gelöscht, Mod gespeichert, PC neugestartet und das Script wieder neu eingebaut. Damit sollte auch jede Möglichkeit einer falschen Kompelierung ausgeschlossen sein.

Code: 
begin kf_skm_conj_field1_script

short state
short doonce

if ( MenuMode == 1 )
	return
endif

if ( state == 0 )
	Disable
	set state to 1
endif

if ( state == 1 )
	if ( GetJournalIndex "kf_skm_conjuration_quest" == 20 )
		if ( kf_skm_conj_solved >= 3 )
			PlaySound3D "conjuration area"
			Enable
			set state to 2
		endif
	endif
endif

if ( state == 2 )
	if ( GetCollidingPC == 1 )
		if ( doonce == 0 )
			MessageBox "Beschwöre eine daedrische Kreatur, die gegen diesen Skamp verliert."
			set doonce to 1
		endif
	else
		if ( doonce == 1 )
			set doonce to 0
		endif
	endif

	if ( GetDistance Player < 1150 )
		if ( Player->GetEffect sEffectSummonScamp )
			MessageBox "Ihr dürft für diese Aufgabe keinen Skamp beschwören."
			Player->RemoveEffects 102
			return
		endif

		if ( Player->GetEffect sEffectSummonClannfear )
			PlaceItem "kf_skm_conj_clannfear1" 4480 4064 14240 0
			Player->RemoveEffects 103
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonDaedroth )
			PlaceItem "kf_skm_conj_daedroth1" 4480 4064 14240 0
			Player->RemoveEffects 104
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonDremora )
			PlaceItem "kf_skm_conj_dremora1" 4480 4064 14240 0
			Player->RemoveEffects 105
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonWingedTwilight )
			PlaceItem "kf_skm_conj_winged1" 4480 4064 14240 0
			Player->RemoveEffects 111
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonHunger )
			PlaceItem "kf_skm_conj_hunger1" 4480 4064 14240 0
			Player->RemoveEffects 112
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonGoldenSaint )
			PlaceItem "kf_skm_conj_golden1" 4480 4064 14240 0
			Player->RemoveEffects 113
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonFlameAtronach )
			PlaceItem "kf_skm_conj_flame1" 4480 4064 14240 0
			Player->RemoveEffects 114
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonFrostAtronach )
			PlaceItem "kf_skm_conj_frost1" 4480 4064 14240 0
			Player->RemoveEffects 115
			set state to 3
		endif

		if ( Player->GetEffect sEffectSummonStormAtronach )
			PlaceItem "kf_skm_conj_storm1" 4480 4064 14240 0
			Player->RemoveEffects 116
			set state to 3
		endif
	endif
endif

if ( state == 3 )
	if ( kf_skm_conj_solved >= 5 )
		Journal "kf_skm_conjuration_quest" 40
		set state to 4
	endif
endif

if ( GetDisabled == 0 )
	if ( GetJournalIndex "kf_skm_conjuration_quest" >= 30 )
		Disable
	endif
endif

end

/EDIT:

Nun habe ich das Problem noch mit einem RightEval erzeugen können. Das hilft trotzdem nicht weiter... (RightEval bezeichnet nicht deklarierte Variablen. Hier sind aber definitv alle Variablen deklariert.)

/EDIT2:

Problem gelöst. Ich sollte aufhören bei mir nach unerklärlichen Fehlern suchen, sondern lieber die Bethforen bemühen. Zur Information:

Die folgenden Abfragen sind (warum auch immer) verbuggt und führen zu seltsamen Fehlern:

GetEffects Paralize
GetEffects RestoreFatigue
GetEffects SummonFrostAtronach
GetEffects SummonLesserBonewalker
GetEffects SummonScamp

Die anderen GetEffects sollten eigentlich funktionieren, solltet ihr aber mal einen unerklärlichen Fehler haben, liegt es vielleicht an einer GetEffects-Abfrage.
 
Zuletzt bearbeitet:
Hallo, ich habe auch ein Problem:

Wenn eine Kreatur stirbt, soll um sie herum ein Frostgebietszauber wirken. Allerdings bekomme ich das nicht so recht gebacken und alles, was ich bisher versucht habe, funktioniert nicht so wirklich...

Könnte mir irgendjemand helfen?

Gruß, Drachenwächter
 
Ich brauche Hilfe bei einem Homecall-Ring.

Ich bräuchte für dein Ring ein script, dass mich auf Anfrage in mein Haus teleportiert. Außerdem soll der Ring mich in die großen Städte wie Balmora, Ald'ruhn, Sadrith Mora ect. bringen können.
Da sollte dann eine Meldung kommen wie "Wohin möchtest du reisen?" und darunter halt die Auswahl:

[-Mein Haus]
-Balmora (Zentraler Vorplatz zwischen dem Schlickschreiter und den Gildenhäusern)
-Ald'ruhn (Großer Platz vor dem Zugang nach Unter-Skar)
-Sadrith Mora (Vorplatz von Tel Naga)
-Molag Mar (Auf dem Dach der Insel, wo der Tempel ist)
-Suran (rechts vom Haus der Irdischen freuden, am Fluss)
-Dagon Fel (kp irgendwo, an der Taverne)
-Geisterpforte (direkt davor halt)
-Maar Gan (am Außenposten/Schlickschreiter)
-Gnisis (auf dem großen Platz, wo auch die Händler stehen)

Für "Mein Haus" sollte in dem Script ein Platzhalter kommen, da ich noch nicht weiß, wo direkt ich mich da hinhaben will xD
Weitere Schritte, die evtl. nötig wären, müsste ich vlt. genauer erklärt bekommen, da ich im CS ziemlich unerfahren bin.

mfg
 
Zuletzt bearbeitet:
Ja schön und gut, allerdings habe ich nach wie vor 0 Ahnung von Scripten und bräuchte daher schon eine passende Version, und keine Grundlagen, die ich ausbauen muss.

(ich will nicht unhöflich klingen, aber ich bin kein leidenschaftlicher Scripter, eher ein Hobby-Modder, der nix besseres kann als Hausmods xD bei diesem aber möchte ich gern, dass es "perfekt" wird. Also bitte ich nochmal um direkte Hilfe. Nichts für ungut!)
 
Dann benutz das hier - ist ein simples Teleportscript, das 10 vordeklarierte Ziele ansteuert, eine Abbruchfunktion hat und auf ein beliebiges ausrüstbares Item gelegt werden kann (Ring, Amulett, Gürtel... Schluffen... Unterhose... was auch immer). Der Clou daran ist, dass dieser Gegenstand nicht wirklich ausgerüstet wird. Also kann man sein normales Item tragen, dies hier bequem auf einen Hotkey legen und es beliebig oft darüber aufrufen, ohne es im Menu zuerst ablegen zu müssen. Ich benutze ein ähnliches Script für Arkngchend R3LOADED, wo man von meiner Questgeberin einen "Dwemer Runenstein" zum Teleportieren erhält. Wie auch immer, hier das Script:

Code: 
begin RuneStoneWarper_SC
short msglevel
short messageOn
short ControlIO
short OnPCEquip
short PCSkipEquip
short Destination

set PCSkipEquip to 1

IF ( OnPCEquip == 1 )
 set OnPCEquip to 0
 set ControlIO to 2
EndIF

IF ( ControlIO != 2 )
 IF ( ControlIO == 1 )
  set msglevel to 0
  set messageON to 0
  set Destination to 0
  set ControlIO to 0
 EndIF
 return
endif

IF ( messageOn == 0 )
 IF     ( msglevel == 2 )
  set msglevel to 1
  MessageBox "ZIEL AUSWÄHLEN:", "> ABBRUCH <", "> WEITER <", "Ziel 01", "Ziel 02", "Ziel 03", "Ziel 04", "Ziel 05"
  set messageOn to 1
 ElseIF ( msglevel == 1 )
  set msglevel to 2
  MessageBox "ZIEL AUSWÄHLEN:", "> ABBRUCH <", "> ZURÜCK <", "Ziel 06", "Ziel 07", "Ziel 08", "Ziel 09", "Ziel 10"
  set messageOn to 1
 ElseIF ( msglevel == 0 )
  set msglevel to 2
  MessageBox "DURCH BALMORA SPRINGEN?" "NEIN" "JA"
  set messageOn to 1
 EndIF
 Return
EndIF

set Destination to GetButtonPressed

IF ( Destination <= 1 )
 IF ( Destination >= 0 )
  set messageOn to 0
 EndIF
 IF ( Destination == 0 )
  set ControlIO to 1
 EndIF
 return
EndIF

set Destination to ( ( Destination - 7 ) + ( msglevel * 5 ) )
playsound "thunder2"

IF	( Destination == 0 )
 player->PositionCell -21792, -12087,  882, 270, "Balmora" 
ElseIF	( Destination == 1 )
 player->PositionCell -23864, -13594, 1335, 270, "Balmora" 
ElseIF	( Destination == 2 )
 player->PositionCell -21323, -18235, 1184,   0, "Balmora" 
ElseIF	( Destination == 3 )
 player->PositionCell -20682, -15185,  320,  90, "Balmora" 
ElseIF	( Destination == 4 )
 player->PositionCell -16670, -12305,  547, 270, "Balmora" 
ElseIF	( Destination == 5 )
 player->PositionCell -17717, -15265,  555, 180, "Balmora" 
ElseIF	( Destination == 6 )
 player->PositionCell -24933, -13259, 1110,   0, "Balmora" 
ElseIF	( Destination == 7 )
 player->PositionCell -24813, -10220, 1375, 180, "Balmora" 
ElseIF	( Destination == 8 )
 player->PositionCell -15120, -14262,  790, 270, "Balmora" 
ElseIF	( Destination == 9 )
 player->PositionCell -24576, -16072,  615,  65, "Balmora" 
EndIF

set ControlIO to 1

End
Du mußt nur im ersten Teil die Zieltasten korrekt benennen und am Ende die Zielkoordinaten eintragen. Dann funktioniert es schon. Naja, es muß noch auf das Objekt deiner Wahl - ich würde dazu ein Amulett oder Ring mit 0 Gewicht empfehlen.
 
  • Like
Reaktionen: Malcador
Du musst dich einloggen oder registrieren, um hier zu antworten.

Ähnliche Themen

Alexi
Construction Set Skriptthread zum Construction Set
Antworten
12K
Aufrufe
846K
[Obl] PlugIns und Mods
Skyrimgamer1
Skyrimgamer1
E
Skriptthread zum Creation Kit
Antworten
593
Aufrufe
83K
[Skyrim] Creation Kit
Destero
Destero
IvanDaVile
Construction Set Level-Up feststellen
Antworten
1
Aufrufe
1K
[MW] Plugins und Mods
IvanDaVile
IvanDaVile
MC Dirty
Construction Set Disable, Enable und Script
Antworten
4
Aufrufe
1K
[MW] Plugins und Mods
MC Dirty
MC Dirty
Fluffy
Construction Set Was mache ich Falsch?
Antworten
5
Aufrufe
1K
[Obl] PlugIns und Mods
Eldarie
E
Oben Unten
Zurück