Construction Set Der Scriptthread

Begin IdV_DontPickup

; this goes to some book/scroll/paper whatever
; the original script was written by Dave Humphrey
; and on some note in his PI Dave's Furniture Store
;if ( OnActivate )
;	Activate
;endif
; is the whole thing and will make any kind of book or scroll impossible to pickup
; but one will be stuck in some wired menumode that ends when hitting the inventory button (right mouse)
; the rest of the script was created by me and will prevent this effect

short io	; inventory open

if ( io )
	Menutest
	set io to Menumode
endif

if ( OnActivate )
	if ( Menumode == 0 )
		set io to 1
	endif
	Activate
endif

End

Begin IdV_CastDetect_Debug

short cost
short fail
short sch

float c
float d
float m
float r

if ( MenuMode )	; cant cast in menumode
	Return
endif

if ( CharGenState != -1 )	; just in case...
	Return
endif

if ( Player->GetSpellReadied == 0 )	; cant cast with your hands down
	Return
endif

set c to ( Player->GetMagicka )	; current magicka
set d to ( m - c )	; difference to old
set m to c	; safe current as old

; get the first (!) frame the cast sound plays
; thats the frame the magicka is removed
; assuming the sound matchs the school, the sch(ool) variable can be used later
; sounds can be changed in 'Gameplay, Magic Settings'
; Player->GetAlteration/Conjuration/Destruction/Illusion/Mysticism/Restoration

if ( Player->GetSoundPlaying "alteration cast" )
	if ( sch == 0 )
		set sch to 1
	endif
elseif ( Player->GetSoundPlaying "conjuration cast" )
	if ( sch == 0 )
		set sch to 2
	endif
elseif ( Player->GetSoundPlaying "destruction cast" )
	if ( sch == 0 )
		set sch to 3
	endif
elseif ( Player->GetSoundPlaying "shock cast" )
	if ( sch == 0 )
		set sch to 3
	endif
elseif ( Player->GetSoundPlaying "frost_cast" )
	if ( sch == 0 )
		set sch to 3
	endif
elseif ( Player->GetSoundPlaying "illusion cast" )
	if ( sch == 0 )
		set sch to 4
	endif
elseif ( Player->GetSoundPlaying "mysticism cast" )
	if ( sch == 0 )
		set sch to 5
	endif
elseif ( Player->GetSoundPlaying "restoration cast" )
	if ( sch == 0 )
		set sch to 6
	endif
elseif ( sch )	; reset if it plays no longer
	set sch to 0
	set fail to 0
endif

; assuming you cant cast while the old sound still plays
; also runs the first time the script is started

if ( sch == 0 )
	set r to 0
	if ( d )
		set r to ( d / GetSecondsPassed )
	endif
	Return
endif

if ( fail )	; once we even know the spell failed, theres nothing left to do
	Return
endif

; While the sound for spellcasting does not need to match the school,
; the failure sound will match it. Though we dont make any use of that.

if ( Player->GetSoundPlaying "Spell Failure Destruction" )
	set fail to 1
elseif ( Player->GetSoundPlaying "Spell Failure Alteration" )
	set fail to 1
elseif ( Player->GetSoundPlaying "Spell Failure Illusion" )
	set fail to 1
elseif ( Player->GetSoundPlaying "Spell Failure Mysticism" )
	set fail to 1
elseif ( Player->GetSoundPlaying "Spell Failure Restoration" )
	set fail to 1
elseif ( Player->GetSoundPlaying "Spell Failure Conjuration" )
	set fail to 1
endif

if ( fail )
	if ( sch > 0 )
		MessageBox "Nicht genug Mana"
	else
		MessageBox "Fehlzündung"
	endif
endif

if ( sch < 1 )	; the cast was already detected and its 'cost' calculated
	Return
endif

set c to r	; this is just for debugging, see last MessageBox

if ( r )
	set r to ( r * GetSecondsPassed )
endif
set d to ( d - r )

set cost to ( d + 0.5 )	; kill rounding error, spellcost are non-negative integers
if ( cost < 0 )
	set cost to 0
endif

MessageBox "Kosten: ~%g (%.3f) M. Regen: %.3f M/s. Korrektur: %.3f M", cost, d, c, r
set sch to -1

End