Construction Set Skriptthread zum Construction Set

Mache einen Doppelklich auf deinen Siedler, unten bei Persistent Reference muss ein Haken hinein, dieser fehlt wahrscheinlich bei dir. Korrigiere dies und es müsste eigentlich zu speichern sein. :)

Außerdem muss es
"begin gamemode"
heißen. ;)

Edit: Was soll dieses Activate nach dem Endif ? Entfern das auch noch.

Mfg Master of Worlds
 
  • Like
Reaktionen: Oblivion freak
die Short Variable Doonce ist auch überflüssig, es sei denn du definierst diese noch.

Am besten du schaust dir erst mal die Grundlagen der Scriptbefehle an. Leider weis sich nicht mehr wo die zu finden sind. Aber da sind zB die Grundsachen alle erklärt und wofür sie da sind und was am wichtigsten ist, wie ein Script im Grundsatz aufgebaut wird. Danach solltest du mit dem Scripten üben anfangen. Vorher hat das so keinen Sinn. Du wirst unsere Hilfen dann nicht verstehen.
 
Zuletzt bearbeitet:
wenn ich wüsste wo es ist dan würd ich das auch alles lernen aber ich habe mir das was ich hab aus nem toturial abgeleitet.. das mit den notizrn vorher klappt auch aber das mit der Person ist halt doof und da fehlr mir ja auch nur noch ein häckchen aber ich finde es einfach nicht das ist bei meinem NPC nicht in dem Fenster wenn ich es öffne ...
 
Hiho!
MoW meint damit den Siedler, den du in der Welt, also im Referenz-Window, platziert hast. Dort öffnet sich beim Klicken ein Fenster, wo du dann oben eine Referenz eingibst. Diese eingegeben Referenz musst du dann letztendlich im Skript benutzen.

Ps: Ich würde als Entfernung nicht "20" nehmen... Das entspricht ungefähr 30 Zentimetern.
 
  • Like
Reaktionen: Oblivion freak
Wenn du im CS im Editor die B taste drückst erscheinen gelbe Linien. Dieser Bereich hat 4096*4096 Pixel. Deine 20 sind also 20 Pixel davon. Du siehst also wie winzig deine Entfernung ist. In Metern wird da nichts gerechnet, auch das mit den 20 cm ist quatch. Das sind Pixeleinheiten und lassen sich wie gesagt auch so veranschaulichen.

Denn sonst wäre die Entfernung von der Betrachtung abhängig. Zoome ich raus sind 1 CM mit dem Metermass fast 200 Pixel. Zoome ich ganz nah ran sind 1 CM mit dem Metermass vieleicht nur noch 10 Pixel. So ungefähr müsst Ihr euch das vorstellen, es ist also Blödsinn in Meter oder cm das sich zu veranschaulichen.

ich bin ja nicht so, also Auf dein Npc gehen den du im Editor plazierst. Rechte Maustaste, Edit und da ist das Fenster wo du das Kreuz setzen musst. Dort kannst du Ihn auch vergrößern und verkleinern. Denn das geht bei NPC nur so.
 
Zuletzt bearbeitet:
  • Like
Reaktionen: Oblivion freak
namen eines NPCs ändern

Wie lautet der script zum namen ändern eines NPCs.
Meine vorstellung:
Code: 
scn namequest

short doonce

begin Gamemode
if player.stage nameaendern >= 10 && doonce == 0
; Jetzt muss der name geändert werdeen bloß wie?
set doonce to 1
endif
end
 
HiHo!

Also, ich würde gern an dem Script von Alba (Begleiter-Mod) etwas verändern. Und zwar dass wenn ich mich setze, sie es mir nachtut. Ich habe mir aus CM Partners schon den passenden Befehl kopiert, ihn an der richigen (denke ich) passenden Stelle eingefügt. Ich speichere das Script ab! un motzt das CS aber herum as in dversen Lines Fehler zu korriegieren wären! Erstens kann ich keine Finden bzw. diese nicht einfac herauslöschen, da sie sehr wichtig sind!

Alba Script :

Code: 
Scriptname TMSklavinScript

short SklavinErstmalsAngesprochen
short HerrschaftsringImSpiel
short SklavinChoice
short SklavinButton
short SklavinButton2
short SklavinFolgtSpieler
short SklavinDoEquip
short SklavinFollowTemp
short SklavinVermeideKampf
short SklavinVermeideKampfAlt
float timer
short talked
short nightline
short sec
ref CRef

;#DINO
float Schleichtimer
float Regenerationstimer
short MomGes
short MaxGes
short MomLev
short PlayerLevel
short MomentaneEntfernung
short SklavinMagieVerbesserung
short MomentaneLaune
short MomMag
short MaxMag
short MomentaneAusdauer
short MaximaleAusdauer
short QuestIstGestartet
short AlbaRekrutierungTag 
short AlbaBegleitdauer
short AlbaBegleitMonat 
short AlbaLiebesRating
short AlbaInBruderschaft
short AlbaInAnvil
short AlbaInParadies
short AlbaWarBewusstlos
short AlbaReitetNicht
short AlbaKuschelt
short AlbaKuschelereignisEingetreten
short AlbaImKittchen
short AlbaImWolkenherrscher
short AlbaResume1
short AlbaResume2
short AlbaResume3
short AlbaResume4
float BlindheitsTimer
short BlindheitsTimerStart



short nureinmal


;#########################################################
; ## Auswahl bei  Anklicken
;#########################################################
Begin OnActivate Player
	
	if ( IsActionRef Player == 1 )
        if TMSklavinRef.IsSneaking == 0
            SetIgnoreFriendlyHits 1
            if (TMSklavinIntroRef.GetUnconscious == 1 )
                Message "Alba kann momentan nicht angesprochen werden."
                Return
            endif
            if ( SklavinErstmalsAngesprochen == 0 )
                TMSklavinIntroRef.Activate Player 1
                Set SklavinErstmalsAngesprochen to 1
    			;#########################################################
    			;# Erstmal soll sie uns nicht folgen, da wir ja noch nix gesagt haben.
    			;#########################################################			
    			Set SklavinFolgtSpieler to 0
    			TMSklavinRef.SetActorValue Marksman 0
    			Wait TMSklavinFollow
                Return
            elseif ( SklavinErstmalsAngesprochen == 1 )
                set DINOAlba.AlbaLiebesRating to AlbaLiebesRating
                SetNoRumors 1
                
                AddTopic AlbaKampf
                AddTopic AlbaKeinKampf
                AddTopic AlbaWiegehtsEuch
                AddTopic AlbaIchWillKlauen
				;# AddTopic AlbaFreiheit ; DEBUG
                RefreshTopicList 
                
                set AlbaBegleitDauer to (GameDaysPassed - AlbaRekrutierungTag)
                set CRef to TMSklavinRef.GetCombatTarget
                if ( TMSklavinRef.IsInCombat == 1 )
                    ;Message "Alba befindet sich im Kampf und kann nicht angesprochen werden."
                    Activate
                    return
                else
                    if SklavinFolgtSpieler == 0
                        
                        if AlbaLiebesRating > 30
                            MessageBox "Was soll Eure Ehefrau Alba tun?" "Schatz, kommst du?" "< Abbruch >"
                        elseif AlbaLiebesRating > 16
                            MessageBox "Was soll Eure geliebte Alba tun?" "Kommst du, Liebste?" "< Abbruch >"
                        elseif AlbaLiebesRating > 8
                            MessageBox "Was soll Eure treue Freundin Alba tun?" "Bitte komm mit mir, Alba" "< Abbruch >"
                        else
                            MessageBox "Was soll Eure Gefährtin Alba tun?" "Begleite mich, Alba" "< Abbruch >"
                        endif                    
                    else
                        
                        if AlbaLiebesRating > 30
                            MessageBox "Was soll Eure Ehefrau Alba tun?" "Ich bin bald wieder da, mein Schatz" "Können wir reden, mein Schatz?" "< Zum Inventar >" "< Kleidung und Waffen verändern >" "< Statistische Werte ansehen >" "< Abbruch >"
                        elseif AlbaLiebesRating > 16
                            MessageBox "Was soll Eure geliebte Alba tun?" "Warte hier einen Moment, Liebste" "Hast du Lust zum plaudern?" "< Zum Inventar >" "< Kleidung und Waffen verändern >" "< Statistische Werte ansehen >" "< Abbruch >"
                        elseif AlbaLiebesRating > 8
                            MessageBox "Was soll Eure treue Freundin Alba tun?" "Warte hier auf mich, Alba" "Lass uns plaudern, Alba" "< Zum Inventar >" "< Kleidung und Waffen verändern >" "< Statistische Werte ansehen >" "< Abbruch >"
                        else
                            MessageBox "Was soll Eure Gefährtin Alba tun?" "Warte hier, Alba" "Wir müssen reden" "< Zum Inventar >" "< Kleidung und Waffen verändern >" "< Statistische Werte ansehen >" "< Abbruch >"
                        endif
                        Set SklavinChoice to 1
                    endif
                    Set SklavinChoice to 1
                endif
            endif
        else
            Message "Ihr könnt Alba im Schleichmodus nicht ansprechen"
        endif
	else
		Activate
	endif

End OnActivate


Begin GameMode

    ; Blindheit timern
    if DINOAlba.AlbaIstBlind == 1
        if BlindheitsTimerStart == 0
            set BlindheitsTimerStart to 1
            set BlindheitsTimer to 0
        endif
        set BlindheitsTimer to ( BlindheitsTimer + GetSecondsPassed )
        if BlindheitsTimer > 15
            Message "Alba schaut nicht mehr weg und wird wieder Verbrechen melden"
            ForceActorValue Blindness 0
            set DINOAlba.AlbaIstBlind to 0
            set BlindheitsTimer to 0
        endif
    else
        set BlindheitsTimer to 0
        set BlindheitsTimerStart to 0
    endif

    ;# Fuer Upgrade Kompatibilität
	if nureinmal== 0
    		if ( SklavinFolgtSpieler == 0 )
    			TMSklavinRef.SetActorValue Marksman 0
    			Wait TMSklavinFollow
    			Set SklavinChoice to 0
                ;# Müdigkeit resetten 
                set DINOAlba.AlbaLetzterSchlafTag to GameDaysPassed
    		endif
		set nureinmal to 1
	endif

	;#########################################################
	;##########  Einmalig den Herrschaftsring adden
	;#########################################################
	if ( HerrschaftsringImSpiel == 0 )
        if SklavinFolgtSpieler == 1
            Player.AddItem 01004CCC, 1
            ;Player.AddItem TMSklavinRing,1
            set HerrschaftsringImSpiel to 1
            ;# Müdigkeit resetten
            set DINOAlba.AlbaLetzterSchlafTag to GameDaysPassed
        endif
	endif
	
	;#########################################################
	;##########  Quest starten
	;#########################################################

	if SklavinErstmalsAngesprochen == 1
		if QuestIstGestartet == 0
			set QuestIstGestartet to 1
			Set AlbaRekrutierungTag to GameDaysPassed
			Set AlbaBegleitDauer to 0
            StartQuest DINOAlba            
		endif
	endif

	;#########################################################
	;##########  Queststages aktualisieren
	;#########################################################

 

        ;# Alba hat bis zur Bewusstlosigkeit gekämpft
        if AlbaWarBewusstlos == 0
            if TMSklavinRef.IsInCombat == 1
                set MomGes to TMSklavinRef.GetAV Health
                set MaxGes to TMSklavinRef.GetBaseAV Health
                if MomGes < (MaxGes / 3)
                    set AlbaWarBewusstlos to 1
                endif
            endif
        endif
        ;# Meldung ausgeben, wenn nicht mehr im Kampf
        if AlbaWarBewusstlos == 1
            if TMSklavinRef.IsInCombat == 0
                set AlbaWarBewusstlos to 2
                set DINOAlba.AlbaWarBewusstlos to 1
                SetStage DINOAlba 27
                set AlbaLiebesRating to AlbaLiebesRating + 2
                set DINOAlba.AlbaLiebesRating to AlbaLiebesRating
            endif
        endif

        ;# Hat Schlafmenü das Kuscheln getriggert?
            if AlbaKuschelt == 1
                set AlbaKuschelt to 2
                set DINOAlba.AlbaKuschelt to 1
                SetStage DINOAlba 16
                set AlbaKuschelereignisEingetreten to 1
            elseif AlbaKuschelt == 3
                set AlbaKuschelt to 4
                set DINOAlba.AlbaKuschelt to 2
                SetStage DINOAlba 19
                set AlbaKuschelereignisEingetreten to 1
            elseif  AlbaKuschelt == 5
                set AlbaKuschelt to 6
                set DINOAlba.AlbaKuschelt to 3
                SetStage DINOAlba 24
                set AlbaKuschelereignisEingetreten to 1
            elseif AlbaKuschelt == 7
                set AlbaKuschelt to 8
                set DINOAlba.AlbaKuschelt to 4
                SetStage DINOAlba 25
                set AlbaKuschelereignisEingetreten to 1
            elseif AlbaKuschelt == 9
                set AlbaKuschelt to 10
                set DINOAlba.AlbaKuschelt to 5
                SetStage DINOAlba 26
                set AlbaKuschelereignisEingetreten to 1
            elseif  AlbaKuschelt == 11 ;# BreakEven Point (Liebesrating 30+, also Liebe)
                set AlbaKuschelt to 12
                set DINOAlba.AlbaKuschelt to 6
                SetStage DINOAlba 31
			 AddTopic AlbaFreiheit
                set AlbaKuschelereignisEingetreten to 1
            endif         
        
	endif

	;#########################################################	
	;########## Check, ob im Kampf, dann Sneaking beenden
	;#########################################################
	if (TMSklavinRef.IsInCombat == 1 && TMSklavinRef.IsWeaponOut == 1)
		SetForceSneak 0
	endif

	if (SklavinFolgtSpieler == 1)	
		;#########################################################
		;########## Sneaking, wenn Player sneakt und NICHT im Kampf ist
		;#########################################################
		if Player.IsSneaking == 0 	
			SetForceSneak 0
		endif
		if (Player.IsSneaking == 1 && TMSklavinRef.IsInCombat == 0)		
			SetForceSneak 1
		endif	
		;#########################################################
		;########## Waffe raus, wenn Player die Waffe zieht
		;#########################################################
		if (Player.IsWeaponOut == 1 && SklavinVermeideKampf == 0)
			SetAlert 1
		else
			SetAlert 0
		endif
		;#########################################################
		;########## Kleiner Helfer, damit das Flittchen dem Player folgt
		;#########################################################
		if TMSklavinRef.IsInCombat == 0
          	if (Player.GetPos z) > ((GetPos z) + 700)
                    MoveTo Player
            	elseif (player.GetPos z) < ((GetPos z) - 700)
                    MoveTo Player
            endif
            if (GetDistance Player > 5500)
               MoveTo Player
            endif
		endif
	endif


    
	;#########################################################
	;##########  auswahlmenü abarbeiten
	;#########################################################

	if ( SklavinChoice == 1 )
		Set SklavinButton to GetButtonPressed
		
		if ( SklavinButton == 0 ) ;# Warten bzw. Folgen bei Minimenu
			if ( SklavinFolgtSpieler == 1 ) 
				TMSklavinRef.SetActorValue Marksman 0
				Wait TMSklavinFollow
				Set SklavinFolgtSpieler to 0
				Set SklavinChoice to 0
                ForceActorValue Blindness 0
                set DINOAlba.AlbaIstBlind to 0
                StartConversation player, AlbaWarteHier 
				Return
			elseif ( SklavinFolgtSpieler == 0 )
				TMSklavinRef.SetActorValue Marksman 1
				StopWaiting TMSklavinFollow
				Set SklavinFolgtSpieler to 1
				Set SklavinChoice to 0
                StartConversation player, AlbaKommMit 
				;##################################################
				;# Wenn sie zum ersten mal folgen soll, wird die Quest-Stage auf
				;# 10 gesetzte und somit der erste Eintrag ausgegeben
				;##################################################

				if GetStage DINOAlba <10
					SetStage DINOAlba 10
				endif

				Return				
			endif
		elseif ( SklavinButton == 1 ) ;# Plaudern  bwz. Abbruch bei Minimenu
			if ( SklavinFolgtSpieler == 1 )
				Activate
                Set SklavinChoice to 0
				Return
			elseif ( SklavinFolgtSpieler == 0 )
				Set SklavinChoice to 0
				Return
			endif
		elseif ( SklavinButton == 2 ) ;# Inventar
            ForceActorValue Blindness 0
            set DINOAlba.AlbaIstBlind to 0
			TMSklavinContainerPlaced.Activate Player 1
			Set SklavinChoice to 0
			Return
            
		elseif ( SklavinButton == 3 ) ;# Kleidung ung Waffen
            ForceActorValue Blindness 0
                set DINOAlba.AlbaIstBlind to 0
			TMSklavinClothContainerRef.RemoveAllItems
			TMSklavinRef.RemoveAllItems TMSklavinClothContainerRef
			TMSklavinClothContainerRef.Activate Player 1
			Set SklavinChoice to 2
			Return	
            
		elseif ( SklavinButton == 4 ) ;# Statistik
        
			Set SklavinChoice to 0
			set MomLev to TMSklavinRef.GetLevel
			set MomGes to TMSklavinRef.GetAV Health
            set MaxGes to TMSklavinRef.GetBaseAV Health
			set MomMag to TMSklavinRef.GetAV Magicka
            set MaxMag to TMSklavinRef.GetBaseAV Magicka   
			set MomentaneAusdauer to TMSklavinRef.GetBaseAV Fatigue
			set MaximaleAusdauer to TMSklavinRef.GetBaseAV Fatigue               
           	if AlbaBegleitDauer < 2
                	if (MomMag > MaxMag) && (MomGes > MaxGes) && (MomentaneAusdauer > MaximaleAusdauer)
                        MessageBox  "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von maximal %.0f Punkten - ist also durch Magie künstlich erhöht, ihre Magie liegt bei %.0f von maximal %.0f Punkten -  ebenfalls künstlich erhöht. Ihre Ausdauer liegt bei %.0f von maximal %.0f Punkten. Auch dieser Wert ist durch Ausrüstung künstlich erhöht." MomLev MomGes MaxGes MomMag MaxMag MomentaneAusdauer MaximaleAusdauer "Weiter"   
                	elseif (MomMag > MaxMag) && (MomGes > MaxGes)
                        MessageBox  "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von maximal %.0f Punkten - ist also durch Magie künstlich erhöht, ihre Magie liegt bei %.0f von maximal %.0f Punkten - ist also ebenfalls durch Ausrüstung künstlich erhöht. Ihre Ausdauer liegt bei %.0f von maximal %.0f Punkten." MomLev MomGes MaxGes MomMag MaxMag MomentaneAusdauer MaximaleAusdauer "Weiter"   
                	elseif (MomMag > MaxMag)
                        MessageBox  "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von maximal %.0f Punkten, ihre Magie bei %.0f von maximal %.0f Punkten - ist also durch Ausrüstung künstlich erhöht. Ihre Ausdauer liegt bei %.0f von maximal %.0f Punkten." MomLev MomGes MaxGes MomMag MaxMag MomentaneAusdauer MaximaleAusdauer "Weiter"             
                	elseif (MomGes > MaxGes)
                         MessageBox  "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von maximal %.0f Punkten - ist also durch Magie künstlich erhöht, ihre Magie liegt bei %.0f von maximal %.0f Punkten. Ihre Ausdauer liegt bei %.0f von maximal %.0f Punkten." MomLev MomGes MaxGes MomMag MaxMag MomentaneAusdauer MaximaleAusdauer  "Weiter"  
                	elseif (MomentaneAusdauer > MaximaleAusdauer)   
                        MessageBox  "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von maximal %.0f Punkten, ihre Magie bei %.0f von maximal %.0f Punkten. Ihre Ausdauer liegt bei %.0f von maximal %.0f Punkten - ist also durch Ausrüstung künstlich erhöht." MomLev MomGes MaxGes MomMag MaxMag MomentaneAusdauer MaximaleAusdauer  "Weiter"                      
                	else
                        MessageBox  "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von maximal %.0f Punkten, ihre Magie bei %.0f von maximal %.0f Punkten. Ihre Ausdauer liegt bei %.0f von maximal %.0f Punkten." MomLev MomGes MaxGes MomMag MaxMag MomentaneAusdauer MaximaleAusdauer   "Weiter"
                	endif
           	 else
                if AlbaLiebesRating >=24 
                    if ( SameSex Player == 0 )
                        MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Alba scheint sich unsterblich in Euch verliebt zu haben. Wenn sie Euch ansieht, dann scheinen eure Augen ein unhörbares, geheimnisvolles Gespräch zu führen, und auf Albas Gesicht erscheint ein versonnenes Lächeln." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "So gefällt mir das"
                    else
                        MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Alba scheint sich unsterblich in Euch verliebt zu haben, obwohl Ihr eine Frau seit. Wenn sie Euch ansieht, dann scheinen eure Augen ein unhörbares, geheimnisvolles Gespräch zu führen, und auf Albas Gesicht erscheint ein versonnenes Lächeln." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "So gefällt mir das"
                    endif
                elseif AlbaLiebesRating >=18 
                    if ( SameSex Player == 0 )
                        MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Alba scheint sich ein wenig in Euch verliebt zu haben. Wenn Sie Euch ansieht, dann geht eine Veränderung in ihrem Gesicht vor sich - sie scheint buchstäblich zu erstrahlen und in ihre großen Augen scheint neues Leben einzukehren." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "Ende"
                    else
                        MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Alba scheint sich ein wenig in Euch verliebt zu haben, obwohl Ihr eine Frau seit. Wenn Sie Euch ansieht, dann geht eine Veränderung in ihrem Gesicht vor sich - sie scheint buchstäblich zu erstrahlen und in ihre großen Augen scheint neues Leben einzukehren." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "Ende"
                    endif
                elseif AlbaLiebesRating >=14 
                    MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. In Albas Augen liegt eine angenehme Wärme. Sie scheint echte und tiefe Freundschaft für Euch zu empfinden." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "Ende"
                elseif AlbaLiebesRating >=10 
                    if ( SameSex Player == 0 )
                        MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Albas Lächeln wirkt herzlich und dankbar. Wenn Sie Euch ansieht, dann hat sie einen Blick, der einen Mann wirklich nervös machen kann. Sie scheint in Euch nicht mehr nur einen Gefährten, sondern einen potentiellen Liebhaber zu sehen." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "Ende"
                    else
                        MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Albas Lächeln wirkt herzlich und dankbar. Sie scheint in Euch nicht mehr nur ihre Gefährtin, sondern eine echte Freundin zu sehen." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "Ende"
                    endif
                elseif AlbaLiebesRating >=5 
                    MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Alba lächelt schüchtern, wenn Sie Euch ansieht, und dieses Lächeln wirkt ehrlich. Offenbar scheint es ihr in Eurer Gegenwart zu gefallen. Ihr habt das Gefühl, dass Alba stets bestrebt ist, möglichst nahe bei Euch zu sein." MomLev MomGes MaxGes MomMag MaxMag AlbaBegleitDauer "Ende"
                    
                else
                    MessageBox "Alba befindet sich auf Stufe %.0f. Ihre Gesundheit liegt bei %.0f von %.0f Punkten, ihre Magie bei %.0f von %.0f Punkten. Sie begleitet Euch seit %.0f Tagen. Ihr Blick sagt, sie erwartet nichts, nicht viel von sich selbst, und nur manchmal etwas von Euch. Doch wenn sie Euch ansieht ... ist da etwas in ihren Augen. Sie scheint sich ständig Gedanken über Euch zu machen." MomLev MomGes MaxGes MomMag MaxMag  AlbaBegleitDauer "Ende"
                endif
            endif
			Return
		elseif ( SklavinButton == 5 ) ;# Abbruch
				Set SklavinChoice to 0
				if ( SklavinFolgtSpieler == 1 )
					AddScriptPackage "TMSklavinFollow"
					StopWaiting TMSklavinFollow
				endif
				Return
		endif

    ;#########################################################
	; # Anziehen/Ablegen steuern
    ;#########################################################
	elseif ( SklavinChoice == 2 )
		short SklavinGlueckAlt
		set SklavinGlueckAlt to TMSklavinRef.GetBaseActorValue Luck
		TMSklavinRef.RemoveallItems
		TMSklavinClothContainerRef.RemoveAllItems TMSklavinRef
		TMSklavinRef.SetAV Luck 0
		EvaluatePackage "TMSklavinClear"
		TMSklavinRef.SetAV Luck 1
		EvaluatePackage "TMSklavinPickup"
		TMSklavinRef.SetAV Luck SklavinGlueckAlt
		EvaluatePackage "TMSklavinPickup"
		if ( SklavinFolgtSpieler == 1 )
			StopWaiting TMSklavinFollow
		endif
		set SklavinChoice to 0
	endif
    
    
	;#########################################################
	;##########  Regenerieren, wenn nicht im Kampf
	;#########################################################
	if (TMSklavinRef.IsInCombat == 0)
        	set Regenerationstimer to Regenerationstimer + GetSecondsPassed
        	if Regenerationstimer > 20
            	set MomGes to TMSklavinRef.GetAV Health
            	set MaxGes to TMSklavinRef.GetBaseAV Health
            	if MomGes < MaxGes
                	if IsInCombat == 0
                    	set MomGes to MomGes + 1
                    	;ModAV Health MomGes
                        ModAV Health 2
                	endif
            	endif
            	;#########################################################
            	;###### Laune gegenüber Player verbessern lassen
            	;#########################################################
            	set MomentaneLaune to (TMSklavinRef.GetDisposition Player) 
            	set MomentaneLaune to (MomentaneLaune + 5) 
                set MomentaneLaune to (MomentaneLaune + AlbaLiebesRating) 
                if MomentaneLaune >=100
                    set MomentaneLaune to 99
                endif 
            	ModDisposition Player MomentaneLaune
            	set Regenerationstimer to 0
        	endif
	endif
     
	;#######################################################################
	;##########  Sicherstellen, dass die Laune immer einigermaßen gut bleibt
	;#######################################################################
	set MomentaneLaune to TMSklavinRef.getdisposition Player
	if MomentaneLaune < (30 + AlbaLiebesRating)
		set MomentaneLaune to (30 + AlbaLiebesRating) - MomentaneLaune
        if MomentaneLaune > 100
            set MomentaneLaune to 100
        endif
		TMSklavinRef.moddisposition Player MomentaneLaune
	endif
    ;#######################################################################
    ;# und das Ganze gleich nochmal... Scheint ein Bug in der Engine zu sein,
    ;# die das notwendig macht
    ;#######################################################################
	set MomentaneLaune to TMSklavinRef.getdisposition Player
	if MomentaneLaune < (30 + AlbaLiebesRating)
		set MomentaneLaune to (30 + AlbaLiebesRating) - MomentaneLaune
        if MomentaneLaune > 100
            set MomentaneLaune to 100
        endif
		TMSklavinRef.moddisposition Player MomentaneLaune
	endif

End GameMode


;# Beim Erscheinen des Schlafen-Menüs

	;#########################################################
	;#########################################################
	;#########################################################


Begin MenuMode 1012
		;# Wenn der Player schläft, leveln wir die Sklavin up.
		If (SklavinFolgtSpieler == 1)
            if ( IsPCSleeping == 1 )
                
                ;##################################################################
                ;## Sklavin zum Spieler bringen und gleichzeitig Health regenerieren
                ;##################################################################
                ForceActorValue Blindness 0
                set DINOAlba.AlbaIstBlind to 0
                
                if ( GetDistance Player >= 400 )
                        TMSklavinRef.MoveTo Player, 128, 0, 0
                        If SklavinMagieVerbesserung == 1
                            set SklavinMagieVerbesserung to 0
                            Message "Alba hat sich Euch genähert, um neben Euch zu ruhen und ihre magischen Fähigkeiten zu verbessern." 
                        endif
                else
                        If SklavinMagieVerbesserung == 1
                            set SklavinMagieVerbesserung to 0
                            Message "Alba hat neben Euch geruht und ihre magischen Fähigkeiten verbessert." 
                        endif
                endif
                ResetHealth
                set DINOAlba.AlbaLetzterSchlafTag to GameDaysPassed

                
                ;# Alba kuschelt
                set AlbaKuschelereignisEingetreten to 0
                if AlbaKuschelt == 0
                    if AlbaLiebesRating > 8
                        set AlbaKuschelt to 1
                        set AlbaKuschelereignisEingetreten to 1
                    endif
                endif
                if AlbaKuschelt == 2
                    if AlbaLiebesRating > 12
                        set AlbaKuschelt to 3
                        set AlbaKuschelereignisEingetreten to 1
                    endif
                endif
                if AlbaKuschelt == 4
                    if AlbaLiebesRating > 16
                        set AlbaKuschelt to 5
                        set AlbaKuschelereignisEingetreten to 1
                    endif
                endif
                if AlbaKuschelt == 6
                    if AlbaLiebesRating > 20
                        set AlbaKuschelt to 7
                        set AlbaKuschelereignisEingetreten to 1
                    endif
                endif
                if AlbaKuschelt == 8
                    if AlbaLiebesRating > 25
                        set AlbaKuschelt to 9
                        set AlbaKuschelereignisEingetreten to 1
                    endif
                endif
                if AlbaKuschelt == 10
                    if AlbaLiebesRating > 30
                        set AlbaKuschelt to 11
                        set AlbaKuschelereignisEingetreten to 1
                    endif
                endif              
                
                ;# Sonstige Nachtereignisse triggern
                set AlbaBegleitDauer to (GameDaysPassed - AlbaRekrutierungTag)
                if AlbaResume3 == 0
                    if AlbaBegleitDauer >= 14 && (AlbaKuschelereignisEingetreten == 0)
                        Set AlbaResume3 to 1
                    endif
                endif
                set DINOAlba.AlbaLiebesRating to AlbaLiebesRating
            endif
		endif
End MenuMode 1012

Der warsch. passende Befehl aus CM Partners :
Code: 
  if sitting == 0 && Player.GetSitting == 3
    AddScriptPackage "cmSitScript"
    set sitting to 1
  endif  
 
endif

if sitting == 1 && Player.GetSitting == 0   ; Forces NPC to rejoin Player after sitting package is complete.
  RemoveScriptPackage
  AddScriptPackage "cmFollowPlayer"
  set sitting to 0
endif


Was ich eingentlich fragen wollte, damit das ganze geht, gibt es eine Möglichkeit das CS zu zwingen ein Script abuspeichern?!

Danke!
 
Zuletzt bearbeitet:
Das interresante ist ja dass ich ohne an dem Script etwas verändert habe ich es nicht einmal abspeichern kann! Die mod geht einwandfrei! Wenn ich das Script einfach nur lade und danach gleich abspeichere geht das nicht...
Wie konnte als der Modder dies?

MfG
 
Du musst dich einloggen oder registrieren, um hier zu antworten.

Ähnliche Themen

E
Skriptthread zum Creation Kit
Antworten
593
Aufrufe
83K
[Skyrim] Creation Kit
Destero
Destero
The Nici
  • Angepinnt
Construction Set Der Scriptthread
Antworten
2K
Aufrufe
259K
[MW] Plugins und Mods
Soul-O-Eater
Soul-O-Eater
A
Construction Set Ver. Fragen zu TES Construction Set
Antworten
6
Aufrufe
1K
[Obl] PlugIns und Mods
Jeeens
J
TheDarkRuler
/[Tutorial-Release] Kreaturen in das Construction Set einbinden
Antworten
13
Aufrufe
2K
[Obl] PlugIns und Mods
Hauptmann Vitellus
H
Maximilian
Construction Set [Tutorial]Augen ins Constructions Set einbinden
Antworten
2
Aufrufe
3K
[Obl] PlugIns und Mods
darklady310187
darklady310187
Oben Unten
Zurück