Construction Set Skriptthread zum Construction Set

scn DAOghmaInfiniumScript

short readOnce
short button1
short button2
short basestrength
short newstrength
short basespeed
short newspeed
short baseagility
short newagility
short baseintelligence
short newintelligence

;Begin OnActivate

;if ( readOnce == 0 ) && ( IsActionREF player == 1 )
;	MessageBox "Do you wish to read the Oghma Infinium?" "Yes" "No"
;	set readOnce to 1
;endif

;End

Begin OnEquip

if ( readOnce == 0 )
	MessageBox "Möchtet Ihr das Oghma Infinium lesen?" "Pfad des Stahls lesen" "Pfad des Schattens lesen" "Pfad des Geistes lesen" "Nichts lesen"
	;set button1 to GetButtonPressed
	set readOnce to 1
endif

End
	

Begin MenuMode

if ( readOnce == 1 )
	
	set button1 to getbuttonpressed
	
	if ( button1 == 0 )
		;MessageBox "INCREASING FIGHTER STUFF"
		Set basestrength to ( player.GetBaseAV Strength )
		set newstrength to ( basestrength + 10 )
		set basespeed to ( player.GetBaseAV Speed )
		set newspeed to ( basespeed + 10 )
		Player.SetAV Strength newstrength
		Player.SetAV Speed newspeed
		ModPCSkill Blade 10
		ModPCSkill HeavyArmor 10
		ModPCSkill Blunt 10
		set readOnce to 4
	elseif ( button1 == 1 )
		;MessageBox "INCREASING THIEF STUFF"
		set basespeed to ( player.GetBaseAV Speed )
		set newspeed to ( basespeed + 10 )
		Player.SetAV Speed newspeed
		set baseagility to ( player.GetBaseAV Agility )
		set newagility to ( baseagility + 10 )
		Player.SetAV Agility newagility
		ModPCSkill Sneak 10
		ModPCSkill Security 10
		ModPCSkill LightArmor 10
		set readOnce to 4
	elseif ( button1 == 2 )
		;MessageBox "INCREASING MAGE STUFF"
		set baseintelligence to ( player.GetBaseAV Intelligence )
		set newintelligence to ( baseintelligence + 10 )
		Player.SetAV intelligence newintelligence
		ModPCSkill Destruction 10
		ModPCSkill Willpower 10
		ModPCSkill Conjuration 10
		ModPCSkill Restoration 10
		set readOnce to 4
	elseif ( button1 == 3 )
		set button1 to 0
		set readOnce to 0
	endif

endif




if ( readOnce == 4 )
	set readOnce to 5
	Player.RemoveItem DAOghmaInfinium 1	
endif

End

scn zzzScriptXYNPC

short checked

Begin onActivate
	if (checked == 0)
	set checked to 1
	endif
activate
end

scn zzzScriptXYDoor

Begin onActivate
	if (zzzRef.checked == 1)
	zzzRef.disable
	endif
	activate
end

scn aaDROrd0HQ07PiratenYrmoKrevakTrigSkript

Short Once
Float Timer

Begin onTriggerActor Player
If ( Once == 0 ) 
	Set Once To 1
	PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	DisablePlayerControls
Endif
End

Begin GameMode
If ( Once == 0 )
	Return
Elseif ( Once == 1 )
	Set Once To 2
	PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	DROrdHQ07YrmoKrevakAppear.PlayGroup Forward 0
Elseif ( Once == 2 )
	If ( DROrdHQ07YrmoKrevakAppear.isAnimPlaying == 0 )
		Set Once To 3
		PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	Endif
Elseif ( Once == 3 )
	Set Once To 4
	PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	TriggerHitShader 5
	DROrdHQ07YrmoRef.Enable
Elseif ( Once == 4 )
	Set Once To 5
	Let Timer := DROrdHQ07YrmoRef.SayTo Player aaDROrdHQ07YrmoKrevakTalk1 1
	PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	PrintToConsole "Calenad - Yrmo Talk - Timer = %.0f" Timer
Elseif ( Once == 5 )
	If ( Timer > 0 )
		Set Timer To ( Timer - GetSecondsPassed )
	Else
		Set Once To 6
		PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	Endif
Elseif ( Once == 6 )
	Set Once To 7
	Let Timer := DROrdHQ07YrmoRef.SayTo Player aaDROrdHQ07YrmoKrevakTalk2 1
	PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	PrintToConsole "Calenad - Yrmo Talk - Timer = %.0f" Timer
Elseif ( Once == 7 )
	If ( Timer > 0 )
		Set Timer To ( Timer - GetSecondsPassed )
	Else
		Set Once To 8
		PrintToConsole "Calenad - Yrmo Talk - Once = %.0f" Once
	Endif
Endif
End