Script - Fehler in der Papyrus.log

Also zuerst sollte man auch für sich selber genauer dokumentieren, was das Skript wie genau macht.

Dann: wird der Zauberspruch zur Sprücheliste des Spielers hinzugefügt, oder soll der Zauber einfach nur ausgesprochen werden, al la Abracadabra und x ist für y Zeiteinheiten verzaubert?
Also beispielsweise, man zieht die Rüstung an, und anschließend werden sternförmig Feuerbälle ausgesprochen, in jede Himmelsrichtung.


Zaubersprüche selber haben auch immer noch gewisse Einstellungen, die sie voneinander unterscheiden. Es gibt verschiedene Zauberspruchtypen, mit verschiedenen Auswahlmöglichkeiten.
Dieses muss genauer untersucht und verstanden werden - erst dann mit dem Scripten weitermachen.

Und dann noch: braucht man überhaupt ein Script, oder reicht nicht auch eine einfache Rüstungsverzauberung?

Manche Einträge in den Logs sind fast unvermeidlich. Manche Funktionen brauchen einen Actor und Mesh, deren 3D geladen ist und wenn man sich durch die Welt bewegt, können Scripte noch laufen, aber die Actors sind bereits entladen.

Folgender Check kann sinnlose Fehler unterdrücken. "if akActor" fragt ab, ob die eingehende Referenz ein Actor und geladen ist.
Event OnEquipped(Actor akActor)
if akActor
akActor.EquipItem(Eigengrau_Armor_SingleSuit, True)
endif

Du kannst und sollst Scripte schreiben, die wiederverwendbar sind. In dem Fall kannt du das problemlos jeder Rüstung anhängen, die im Stealth-Modus einen bestimmten Spell kriegen soll. Mit dem selben Script kannst du Rüstung A Effekt A zuweisen und Rüstung B Effekt B oder auch A.

Wenn du willst, dass beim Anziehen eines Helms der Spieler einen Helm-Spell kriegt und beim Anziehen der Rüstung einen Rüstung-Spell, dann reicht dafür ein Script.
Dass Script könnte sich AddSpellOnEquip nennen und hat eine Eigenschaft MySpell. Deises Script lässt sich je dem Helm und der Rüstung zuweisen und die Eigenschaft ist jeweils der richtige Spell zur Rüstung.

Du möchtest, dass ein Effekt auf einem Rüstungsteil beim Schleichen etwas tut. Ich überlege mir gerade, ob das mit einer regulären Verzauberung auf der Rüstung gehen würde. Der Magic-Effect würde hinter einer Condition IsSneaking oder so ähnlich liegen, dann würde dass nur aktiviert, wenn du schleichst.

In solchen Fällen würde ich zuerst abchecken, ob es im Vanilla-Game bereits etwas Ähnliches hat. Hat nicht eine Rüstung der Diebes- oder Assassinen-Gilde sowas ähnliches?

Eine andere gute Anlaufstelle ist der Script-Manager, da kannst du nach Begriffen wie Equip suchen und dir die Scripte ansehen. Es gibt für viele Dinge irgend ein generisches Script, das du ab der Stange nehmen kannst.
Oder du suchst nach OnEquip mit Notepad++ in PSC-Dateien.

Ich habe von diesem PC aus keinen Zugriff auf die Scripte und es ist auch noch zu früh am Tag. Kann aber heute abend auch mal nachsehen.

Scripte werden in Saves gespeichert, muss es ja auch, sonst weiss die Engine nicht, wo ein Script stand, wenn du gespeichert hast. Theoretisch könnte ich jemanden dafür bestrafen, dass er meine Mod deinstalliert hat, ohne dass er es merkt, indem ich Plotstopper scripte. Generell sollte man gescriptete Mods oder Scripte nicht in einem laufenden Durchgang entfernen.

Den Script Manager findet man im Dropdown Gameplay oder so rechts oben.

Ist alles Gewöhnungssache, es gibt Zeug, das im CK besser geht und anderes in XEdit.

@Eigengrau:
Warum nicht einfacher?
Dein Script:

Event OnEquipped(Actor akActor)
if akActor == Game.GetPlayer()
Game.GetPlayer().AddSpell(SpellAnzug_Stealth, True)
Game.GetPlayer().AddSpell(SpellHut_Detect, True)
endif
EndEvent

Dein Script als universal:


Spell Property SpellToAdd Auto
{AnzugSpell oder HutSpell, je nachdem auf welchem Rüstungsteil das liegt}

Event OnEquipped(Actor akActor)

if akActor == Game.GetPlayer()
Game.GetPlayer().AddSpell(SpellToAdd)
endif
EndEvent

Dein Script als universal MIT Message und Item ins Inventar:


Spell Property SpellToAdd Auto
{AnzugSpell oder HutSpell, je nachdem auf welchem Rüstungsteil das liegt}

Message Property myMessage auto
{Nachricht die gezeigt werden soll}

MiscObject Property MyItem auto ;Je nachdem was für ein Item das sein soll, bei Buch "Book Property", Waffe "Weapon Property", Rüstung "Armor Property" usw
{Mein Ding das der Spieler Ins Inventar Bekommen Soll}

Event OnEquipped(Actor akActor)

if akActor == Game.GetPlayer()
Game.GetPlayer().AddSpell(SpellToAdd)
Game.GetPlayer().AddItem(MyItem,1)
myMessage.Show()
endif
EndEvent


Dann ruft er immer nur den Spell auf, den du im Property SpellToAdd angegeben hast. Wenn das Script aufm Anzug liegt, gibst deinen AnzugSpell (und dein AnzugItem und deine AnzugMessage)an, wenns aufm Hut liegt, den HutSpell (und HutItem und HutMessage), also ein Script für beide Teile, du musst nur dementsprechend die Properties ändern.
Ich hatte mir da für die Mausnthamz eins gebaut, da ich nur einen Spell auf einem Teil brauchte, aber da gibts schon eins (Dlc2AddSpellsOnEquip oder so ähnlich) für 3 Spells OnEquip.

LG

Eigengrau schrieb:

Gehören die If-Abfragen jeweils in ein eigenes OnEquipped-Event? Oder darf man diese Events gar nicht mehrmals innerhalb eines einzigen Scripts aufrufen!?

Zum Vergrößern anklicken....

Ich verstehe deine Frage nicht. Das Event ist das Anziehen des Rüstungsteil und das ganze Ding kommt in das Rüstungsteil was du anziehst.
Du kannst soviele ifs im Event haben wie du brauchst, du musst nur drauf achten, dass sie auch abgeschlossen werden und sich nicht gegenseitig ausklammern oder aushebeln. Das ist eigentlich scho alles wenn mich nicht alles täuscht - aber ich täusche mich gern Vor allem, wenn ich vom Skripten nun mal so gar keine Ahnung habe =P
Ich bin gespannt, ob's so funzt - wovon ich jetzt stark ausgehe.

Eigengrau schrieb:

Frohes Festtage euch

Zum Vergrößern anklicken....

Danke, dir auch =)

Ich würde auf der Creation Kit-Seite alle Einsteiger-Materie durchlesen:
https://www.creationkit.com/index.php?title=Category:Papyrus

Ich würde dir auch vorschlagen, mal in den Source-Ordner zu sehen und interessant klingende Scripte mit dem Notepad++ anzusehen, damit du ein Gefühl dafür kriegst, wie gescriptet wird und wie Dinge umgesetzt wurden.
Ich habe so das Payrus-Scripting gelernt und wenn ich im Zweifel bin, wie ich etwas umsetze, schaue ich mir ähnliche Scripte an. Wobei ich den Vorteil hatte, dass ich bereits mit einigen Script-Sprachen arbeite.

Ausserdem kannst du im Script Manager mit rechter Maustaste auf die Scripte und "Use Info" klicken. Da sieht man, wo die betreffenden Scripte genutzt werden. Man kann ja nicht jedes beleibige Script an jedes beliebige Objekt anhängen. Das "extends" erweitert z.B. ein Basis-Script MagicEffect(jedes Objekt im CK hat ein Basis-Script, auch wenn es sich nicht scripten lässt) und du kannst so ein Script nicht einem Actor zuweisen.
Lustigerweise kannst du aber in einem MagicEffect-Script gleich coden wie in einem Actor-Script, weil MagicEffect sowas wie eine Erweiterung eines Actors darstellt.

Die Events sind eine Schnittstelle zu Ereignisen, die ein Objekt registrieren kann. OnEnterBleedout kann z.B. in einem Actor-Script genutzt werden, aber nicht in einem Armor-Script.

Hier alle Möglichkeiten, die es für einen Actor gibt, unten sind alle Events gelistet, die dieses Script empfängt.
https://www.creationkit.com/index.php?title=Actor_Script

Huhu,
So wie du das Script jetzt gepostet hast bekommst du zwei Spells wenn du das Teil anlegst.
Bildlich gesprochen:
Du rüstest das Rüstungsteil aus und das Script sagt „Hey, ich bin dran, gleich mal checken ob das der Spieler ist, der das anhat (if akActor...). Cool, das isser, also bekommt der gleich nen Spell für die Rüstung. Ok, weiter im Text: erstmal checken ob das der Spieler ist, der das anhat (das 2. if akActor...). Sehr geil, isser, dann bekommt der auch noch den HutSpell mit drauf“

Machs doch einfacher, so wie das Script, das ich oben gepostet hab: eine Abfrage ob Spieler, wenn ja, dann ein Spell, festgelegt durch ein Property.
Dadurch kannst du auch beim unequip bei nur einem Spell bleiben, der entfernt werden soll.

LG

Die liebe Edith:
Nur um mal die Grundbedingungen nochmals rauszukramen.
- das Script wird auf beide Rüstungsteile gelegt
- wenn es auf der Rüstung liegt füllst du das Property von SpellToAdd mit deinem Rüstungszauber
- wenn es auf dem Hut liegt füllst du es mit dem Hutzauber

Ich glaube, dass es gerade ein Verständlichkeitsproblem gibt, da du das ganze in XEdit machst?
Im CK legst das Script drauf, klickst auf Properties und holst dir ausm Klappmenü den entsprechenden Zauber. Und das einfach bei jedem Rüstungsteil einzeln, das du mit dem Script belegt hast. Wie das aufm XEdit funzt weiss ich nicht

@Eigengrau
So, Schau mal, das ist das VanillaScript aus dem Dawnguard DLC:

Scriptname DLC2defaultAddSpellsOnEquipScript extends ObjectReference ;den Kopf des Scripts generiert das CK selber sobald du den Namen angegeben hast
{Generic script for adding spells to an actor when an item is equipped.}

Spell property SpellToAdd01 Auto
Spell property SpellToAdd02 Auto
Spell property SpellToAdd03 Auto

Event OnEquipped(Actor akActor) ;Du hast gerade deine Rüstung angezogen
if (SpellToAdd01 != None) ;da checkt das Script ob bei SpellToAdd01 was eingetragen ist. d.h. wenn da keiner eingetragen ist, sucht das Script nach keinem
akActor.AddSpell(SpellToAdd01) ; Wenn JA, dann bekommst du hier den ersten Spell
EndIf
if (SpellToAdd02 != None) ;Check fürn 2.Spell
akActor.AddSpell(SpellToAdd02) ;Wenn JA, hier bitteschön
EndIf
if (SpellToAdd03 != None) ;wie oben
akActor.AddSpell(SpellToAdd03)
EndIf
EndEvent

Event OnUnequipped(Actor akActor) ;Du hast gerade die Rüstung wieder ausgezogen
Spell left = akActor.GetEquippedSpell(0)
Spell right = akActor.GetEquippedSpell(1)
if (SpellToAdd01 != None) ;Check ob erster Spell eingetragen (A)
if (left == SpellToAdd01) ;Wenn JA (A), dann check ob links ausgerüstet (B)
akActor.UnequipSpell(SpellToAdd01, 0) ;Wenn JA (B), dann Spell raus aus der Hand
EndIf ;Check Links (B) fertig
if (right == SpellToAdd01) ;Check ob rechts ausgerüstet (C)
akActor.UnequipSpell(SpellToAdd01, 1) ;Wenn JA (C), dann Spell raus aus der Hand
EndIf ;Check rechts (C) fertig
akActor.RemoveSpell(SpellToAdd01) ;Spell in die Tonne kloppen bis wieder Rüstung/Ring/Hut/etc ausgerüstet
EndIf ;Check ob eingetragen (A) fertig
;**************Selbiges Spiel wie oben************
if (SpellToAdd02 != None)
if (left == SpellToAdd02)
akActor.UnequipSpell(SpellToAdd02, 0)
EndIf
if (right == SpellToAdd02)
akActor.UnequipSpell(SpellToAdd02, 1)
EndIf
akActor.RemoveSpell(SpellToAdd02)
EndIf
if (SpellToAdd03 != None)
if (left == SpellToAdd03)
akActor.UnequipSpell(SpellToAdd03, 0)
EndIf
if (right == SpellToAdd03)
akActor.UnequipSpell(SpellToAdd03, 1)
EndIf
akActor.RemoveSpell(SpellToAdd03)
EndIf

Also du bräuchtest rein theoretisch nicht mal ein eigenes Script schreiben, sondern kannst einfach auf "Add" im Reiter Scripts (in deinem Objekt), dann im Suchfeld den Namen eintragen. Dann Properties eintragen, fertig
Hoffe du kannst was mit meinen Farben und (A)s, (B)s und (C)s anfangen.

Schöne Feiertage

Richtige Programmierer fangen die Events ab, bevor sie entstehen. Das ist schon richtig mit else.
Du bräuchtest ein Script, was prüft ob du das Ding anhanst, dann prüft ob Bedingungen erfüllt sind - Wenn Rüssi 1 an -> prüfe ob Rüssi 2 an, else (dann) Zauber ->
else if (Wenn nicht) dann nur den Zauber, usw.

Programmieren kann nicht jeder - es bedarf einer eigenen Logik dahinter da du Sachen schon von vorneherein ausschließen solltest, an die du noch gar nicht gedacht hast.
Wie in deinem Fall, was ist wenn Rüssiteil angelegt ist, Teil zwei, drei, vier und fünf aber nicht... usw. und was soll dann passieren.
Die Entwickler haben hier vielleicht nicht gerade gespart ja, doch auf verschiedene Globalen gesetzt, die im Einzelfall Mist waren und gedacht es fällt eh keinem auf!
Tut es auch nicht, denn ungemoddet verpackt die paar Fehlermeldungen die Engine ziemlich gut.
Kompliziert wurde es nur, als Programmier-Modder sich "einmischte". Und auch so, sind Vanilla viele Scripte drin, die einmal anlaufen und dann nie wieder resettet werden. Dabei ist alles vorhanden. Man hat es nur nie mit... und jetzt sag ich was was ich sonst nie sage: "Mit der nötigen Sorgfalt" eingepflegt. Warum auch immer. =/

Eigengrau schrieb:

Hui, das ist eine Menge. Ersteinmal vielen Dank an euch alle für die Antworten und die Mühe!

Wie gesagt habe ich von scripten nun nicht viel Ahnung und möchte mich da aber auch nicht groß einlesen da mir dafür einfach die Zeit fehlt, gerade in diesen elenden Feiertagen.

Von früher her kenne ich es aber zumindest noch so dass eine If-Abfrage oft mit Then und mit else weitergeführt wird. Nur als grobes Beispiel (ungetestet - man könnte auch einen GoTo-Ankerpunkt einstreuen statt den Wert Nothing):

if akActor == Game.GetPlayer()
then Game.GetPlayer().AddSpell(SpellAnzug_Stealth, True)
else nothing
endif

Wie dem auch sei sollte ja alles in ein Script untergebracht werden und da liegt mein Problem. Alles was in einem Event steht (im OnEquipped-Event) wird immer ausgeführt (wenn nicht gesondert gekennzeichnet durch Code). Wie .mausetot es schon richtig schreibt bekomme ich bisher beide Spells auferlegt egal was ich davon nun trage. Im Script von .mausetot wird von einem Spell ausgegangen, was dann ja auch funktioniert. Aber nicht mit 2 Spells in einem Script und dazu wurde mir hier ja quasi geraten das in einem Script unterzubringen.

Natürlich funktioniert die Sache auch mit 2 Spells, wie schon in meinem Eingangspost, aber dann gibt es immer eine Fehlermeldung in der Papyrus.log da das andere Rüstungsteil (wenn ich nur eines trage) vom Spiel nicht gefunden werden kann. Und rufe ich die beiden Spells einzeln im selben Event auf mit einer einfachen If-Abfrage dann kommt es ebenfalls zu einer Fehlermeldung da das Event ganz abgearbeitet wird.

Bei dem Dawnguard DLC Script ist es quasi dasselbe. Das Script scheint von einem festen Fakt auszugehen (Item angezogen = Spell) aber nicht auf ein Szenerio/Check ob das Item auch vorhanden ist und den Code nur dann auszuführen und andererseits den Code zu überspringen. Die Eigenschaft akActor sagt ja nur aus dass es sich um den Spieler handelt, nicht ob das Item gerade aktiv ist (und wenn es so sein sollte dann funktioniert es nicht).

Im Script habe ich 2 Eigenschaften/Property definiert/eingetragen für meine 2 Spells und diese werden mir auferlegt beim anziehen da die Property vorhanden und eingetragen sind. Nur habe ich z.B. gerade nur das eine Rüstungsteil an aber nicht den Hut, das Script arbeitet die Abfrage im Event trotzdem komplett ab und die für den Hut kann ja nicht ausgeführt werden da ich den gar nicht trage. Also wird in der Papyrus.log wieder ein Fehler notiert.

Ich bin mir sicher dass man da etwas daraus basteln kann doch mir ist das zu kompliziert, auch da ich es derzeit nur einmal brauche. Und Bethesda scheint da recht schlampig zu sein mit seinen eigenen Scripts, ein Blick in die Papyrus.log sieht echt schlimm aus.

Daher belasse ich es jetzt erst einmal bei meinen 3 Einzelscripts, das ist nicht die Welt und ich persönlich erkenne da nun nichts negatives dran. Ich bedanke mich jedenfalls recht herzlich bei allen die mir hier geantwortet haben und helfen wollten und vor allem auch bei .mausetot für die Mühe und das tolle, bunte, Auskommentieren!

Ich hoffe ihr hattet alle frohe Festtage und habt schöne Leckereien gegessen!

Zum Vergrößern anklicken....

Heyho, gerne

Vielleicht stehe ich gerade auf dem Schlauch, aber irgendwie check ich gerade nicht worauf du rauswillst. Willst du dass die Spells erst gegeben werden, wenn du beide Rüstungsteile anhast? Also EIN Rüstungsteil KEIN Spell, ZWEI Rüstungsteile ZWEI Spells? Oder Hut an, Hutzauber geben, Rüstung an,RüstungsSpell geben?
Wenn zweiteres der Fall ist, ist das Vanillascript, das ich oben gepostet hab, genau das richtige, denn:

"Aber nicht mit 2 Spells in einem Script und dazu wurde mir hier ja quasi geraten das in einem Script unterzubringen.", und ich finde die Stelle nicht, an der dir dazu geraten wurde.

Aber eine Stelle hab ich gefunden, von @PixelMurder glaub:
"Du kannst und sollst Scripte schreiben, die wiederverwendbar sind.".
Und das heisst nix anderes, dass man Scripte schreiben sollte, die mehrfach eingesetzt werden können, und das geht mit dem Zauberwort Property
Da ich nicht weiss inwieweit du dich mit dem CK auskennst, nochmal Krümel für Krümel:

(im Creation Kit)
-du baust dir ne Rüstung
-du legst das Script vom oberen Post auf die Rüstung
-du bearbeitest per Klappmenu in den Properties vom Script deine Properties (SpellToAdd) und füllst das mit dem Rüstungszauber.
-Rüstung fertig

dann

-du baust einen Hut
-du legst genau das gleiche Script vom oberen Post auf den Hut
-du bearbeitest per Klappmenu in den Properties vom Script deine Properties (SpellToAdd) und füllst das mit dem Hutzauber
-Hut fertig

Und das ist das was @PixelMurder damit meinte (verbesser mich falls ich falsch liege Mr. Pixel ):
Zwei Items - ein Script, das du für beide, oder noch für Stiefel, oder nen Ring , oder ne Halskette usw nutzen kannst, ohne dass nachher in deinem Ordner Scripts:

(Beispielnamen)
OnEquippedAddHutSpellScript
OnEquippedAddRuestungSpellScript
OnEquippedAddRingSpellScript
OnEquippedAddStiefelSpellScript
usw

drin sind, sondern nur ein Script, das für jeden ausrüstbaren Gegenstand benutzt werden kann.
Oder halt auch kein neues, wenn du das Vanillascript nimmst

(Um mal beim If-Then Basic zu bleiben: die Properties sind deine Variablen, und die können für jeden Einsatz(ort) des Scriptes neu festgelegt werden, OHNE dass du das Script ändern musst. Das Property Fenster ist quasi so ein kleiner Manager, die dir die angegebene Variable definiert, OHNE dass du erneut ins Script selber eingreifen musst um was zu ändern. Deswegen kannst du den Spell auch nur über diese SpellToAdd-Variable angeben, und nicht direkt mit Editor ID)

"Bei dem Dawnguard DLC Script ist es quasi dasselbe. Das Script scheint von einem festen Fakt auszugehen (Item angezogen = Spell) aber nicht auf ein Szenerio/Check ob das Item auch vorhanden ist und den Code nur dann auszuführen und andererseits den Code zu überspringen. Die Eigenschaft akActor sagt ja nur aus dass es sich um den Spieler handelt, nicht ob das Item gerade aktiv ist (und wenn es so sein sollte dann funktioniert es nicht)."

Natürlich prüft das Script nicht welches Item vorhanden ist, da das ja auf GENAU DEM ITEM liegen soll das dir nen bestimmten Spell gibt, und wenn du dann GENAU DAS ITEM anziehst muss es ja vorhanden sein, sonst kannst es ja nicht anziehen. Deswegen hast du das Script ja auf jedem Teil drauf, das dir nen Zauber geben soll. Sonst müsstest du, wenn du die Rüssi anziehst, im Script abfragen ob du den Hut auch auf hast, und wenn JA, dann auch noch den Hutzauber geben (und andersrum genauso), und je weniger "querverweisende Abfragen" du hast, umso schneller läuft das Script, da es nicht erst auf Rückmeldung warten muss.

Eigentlich ist das ganze recht easy, wobei ich natürlich auch zugeben muss, dass ich eigentlich überhaut nicht scripten kann. Ich suche mir ein paar Scripte raus, die das machen, was ich vorhabe, kopiere mir die benötigten Sachen raus, dann bringe ich die in einem Script unter, das alles zusammen das macht, was die Scripte eigentlich einzeln gemacht hätten, und das zu den Bedingungen, die ich brauche (OnEquipped, OnActivate, usw.)
Ich denke, dass das was es bei dir komplizierter macht, die Tatsache ist, dass du das hauptsächlich im XEdit machst, und nicht im CK.

LG und schöne Restfeiertage

Ach lol... er macht das über XEdit? Okay... das erklärt dann einiges und ich bin hier raus ^^" Ich dachte er guckt sich die Scripte im CK auch mal an *rolleyes

Moorkopp schrieb:

Ach lol... er macht das über XEdit? Okay... das erklärt dann einiges und ich bin hier raus ^^" Ich dachte er guckt sich die Scripte im CK auch mal an *rolleyes

Zum Vergrößern anklicken....

Hat er zumindest oben mal was erwähnt